VAR FIRST
VAR ROK
VAR RX
VAR RY
var Alt
var temp
var TargetCount
var ROKRNG
var EmergPitch
var Num
var Chaff
var Flare
var JamFC
var JamRad

IF Init THEN {
SensorEnable "P3 ESM" 0
SensorEnable "Stargazer" 0
SensorEnable "ARAR-13A" 0
SensorEnable "S3 ESM" 0
	IF ( DBCMFlags & 1 ) == 1 THEN { Chaff = 1 } ENDIF
	IF ( DBCMFlags & 2 ) == 2 THEN { Flare = 1 } ENDIF
	IF ( DBCMFlags & 4 ) == 4 THEN { JamRad = 1 } ENDIF
	IF ( DBCMFlags & 16 ) == 16 THEN { JamFC = 1 } ENDIF
	SensorEnable "FCRadarJam" 0
	SensorEnable "RadarJam" 0
	FIRST = 0
	ROK = 0
} else {

If ( NUM == 0 ) Then {
	If NOT ( ORDER $= "TRANSIT" ) Then {
		SetPersist 1 SetPriority 255 setcrs xybrg ( WayPtX - ownx ) ( WayPtY - owny )
	} Endif
} Endif

IF NEWTRACK THEN {
	; Missile?
	IF ( TgtClass $= "MISSILE" ) AND ( ( TgtMissileClass "AAM" ) OR ( TgtMissileClass "SAM" ) ) THEN {
		SETTACTIC "AirEvadeMissile"
	} ELSEIF ( TgtClass $= "MISSILE" ) AND ( TgtType $= "Torp" ) AND ( ( TgtID $= "Hostile" ) OR ( TgtID $= "UAE" ) ) AND NOT ( ORDER $= "TRANSIT" ) THEN {
;		DEBUGOUT "Registry UGM Missile Launch Point"
		IF not ROK THEN {
			RX = TGTX
			RY = TGTY
			ROK = 1
		} elseif ROKRNG > XYBRG ( RX - OWNX ) ( RY - OWNY ) then {
			RX = TGTX
			RY = TGTY
		} ENDIF
	} elseIF ( TgtClass $= "AIR" ) AND ( ( TgtID $= "HOSTILE" ) OR ( TgtID $= "UAE" ) OR ( TgtID $= "UPD" ) ) THEN {
		; Enemy Plane?
		SETTACTIC "AirEvadeAir"
	} elseIF ( TgtClass $= "SURF" ) AND ( ( TgtID $= "HOSTILE" ) OR ( TgtID $= "UPD" ) ) AND NOT ( TgtType $= "SUB" ) THEN {
		; Enemy Surf?
		TargetCount += 1
		ROK = 0
		SETTACTIC "AirAtkSurf"
	} ElseIF ( TgtClass $= "SUB" ) OR ( ( TgtClass $= "SURF" ) AND ( TgtType $= "SUB" ) ) AND ( ( TgtID $= "UPD" ) OR ( TgtID $= "HOSTILE" ) ) THEN {
		; Enemy Sub?
		TargetCount += 1
		ROK = 0
		SETTACTIC "ASWPlane2"
		FIRST = 1
	} ENDIF
} ENDIF

IF terrainalt > -10 then {
ALT = ( OWNALT - TERRAINALT )
IF ( ( Alt < 2400 ) AND ( PITCH < -0.2 ) ) OR ( ALT < 150 ) THEN {
IF ALT < 800 THEN {
	SetPriority 254 SetPITCH 25
} ELSE {
	; DEBUGOUT "PLANE Stall, Pull Up"
	SetPriority 254 Setalt ( alt + 2000 + TERRAINALT )
} ENDIF
} ENDIF
} ENDIF
If OwnAlt < 1000 Then {
	if pitch < -17 then {
	EmergPitch = ( Pitch * 0.5 )
	SetPersist 1 SetPriority 255 SetPITCH EmergPitch
	} endif
} endif

; Check Up Point Missile Start
IF ( TargetCount == 0 ) AND ROK AND NOT ( ORDER $= "TRANSIT" ) THEN {
	TEMP = XYBRG ( RX - OWNX ) ( RY - OWNY )
	SetPriority 240 STEERXY ( RX - OWNX ) ( RY - OWNY )
	IF terrainalt > -10 then { alt = ( 2000 + TERRAINALT + rnd ( 30 ) ) } else { alt = 450 } endif
	SetPriority 240 setalt alt
	ROKRNG = xyrng ( OwnX - RX ) ( OwnY - RY )
	IF ROKRNG < 500 THEN { ROK = 0 } ENDIF
} ENDIF
IF LOSTTRACK THEN {
	; decrement target count
	; lets make sure our variable doesn't go negative!
	IF TargetCount > 0 THEN { TargetCount -= 1 } ENDIF
} ENDIF
} endif