; -Reinforce Alert- Mod v 1.41

var PreenableCourse
var RunToEnable
var Runout
var lastX
var lastY
var run
var Waypoints
var DecoyLogic
var Spoofed
var UWD
VAR ZALT
var TINIT
VAR NUM_TH
VAR ZZZConf
var TX
VAR TY
var talt
var temp
var Delta
var AltCruise
var PreSet
var FinalPhazeN
var TP
var d
var cd
var inair

IF INIT THEN {
	TP = -1
	cd = 1
	lastX = OwnX
	lastY = OwnY
	PreSet = 1
	ZALT = ( MAXALT * 3.28 )
	TINIT = ( TIME + 0.5 )
	FinalPhazeN = 3000
} ELSEIF ( Runout != -1 ) AND ( run > Runout ) THEN {
	Runout = -1
	SHUTDOWN
} ELSEif ( tp != -1 ) and ( time > tp ) then {
	detonate
} else {
	IF PreSet THEN {
		IF ( RunToEnable < 1 ) Then { RunToEnable = 200 } endif
		PreSet = 0
		DecoyLogic = 75
		Spoofed = RND 100
		IF ( OwnName $= "IDAS" ) THEN { AltCruise = 1000 inair = 1 } ENDIF
		IF ( Pitch < 70 ) AND ( OwnAlt > 0 ) AND NOT inair Then { ShutDown } ENDIF
	} ENDIF

	IF OwnAlt > 0 THEN { UWD = 1 } ELSEIF ( OWnAlt < 0 ) AND UWD THEN { Shutdown } ENDIF
	run += xyrng ( OwnX - lastX ) ( OwnY - lastY )
	lastX = OwnX
	lastY = OwnY

	IF ( TINIT < TIME ) AND ( OWNALT > 0 ) THEN {
		SETPRIORITY 252	SETALT AltCruise
		SETPRIORITY 252	SetSpd MaxSpd
		IF NUM_TH == 0 THEN {
			IF Waypoints THEN {
				IF ( OwnName $= "Harpoon User" ) Then {
					SETPRIORITY 224
					TerminalHome
				} ELSE {
					SETPRIORITY 224
					PreenableCourse
				} ENDIF
			} ELSE {
				SETPRIORITY 224 SetCrs PreenableCourse
			} ENDIF
		} else {
			temp = XYRng ( tx - ownx ) ( ty - owny )
			if d and cd then {
				cd = 0
				tp = ( ownspd * 0.5144444 )
				tp = ( time + 3 + ( temp / tp ) )
			} endif
			if temp > 1000 then {
				d = 1
				SETPRIORITY 250 steerxy ( tx - ownx ) ( ty - owny )
				if ( temp < 5000 ) or ( talt > 50 ) then {
					DELTA = ( TALT - OWNALT + 30 )
					AltCruise = Talt
					temp = XYBRG ABS DELTA ( temp * 3.28 )
				IF DELTA < 0 then { temp = ( -1 * temp ) } endif
					SETPRIORITY 253
					SetSpd MaxSpd
					SETPRIORITY 253
					SETPERSIST 1
					SETPITCH TEMP
				} endif
			} endif
		} endif
	} ENDIF
	IF RunToEnable != -1 THEN {
		IF run >= RunToEnable THEN {
			ENABLE
			RunToEnable = -1
		} ENDIF
	} ENDIF
	IF NEWTRACK then {
		IF ( TgtType $= "CM" ) THEN {
			IF Spoofed > DecoyLogic THEN {
				SetTactic "TH_ST"
		} ELSEIF Spoofed <= DecoyLogic THEN {
			Drop
			} endif
		} ELSEIF Tgtconf > ZZZConf THEN {
			SetTactic "TH_IDAS"
		} ELSE {
			SetTactic "SBROS"
		} ENDIF
	} ENDIF
} ENDIF
IF ( OwnAlt >= ZALT ) Then {
	Shutdown
} ENDIF
